批处理文件小技巧

1 批处理|多服务多窗口

@echo off  
start cmd /k "d:&&cd d:\123&&echo 这是一个窗口&&pause&&ping 192.168.1.3&&ping 172.168.1.10"  
start cmd /k "d:&&cd d:\321&&echo 这是另一个窗口&&pause&&ping 192.168.1.20"

#参数说明
1、start 用来启动一个应用
2、cmd /k 表示cmd后面的命令执行完后不关闭窗口。如果要在执行完成后关闭窗口可以用/c 。详细请使用cmd/?查看
3、”命令1&&命令2&&..” 将要执行的多条命令使用引号全部包起来，并且在命令间用&&分隔。如果只有一条命令则不用引号也可以。

2 批处理|choice的使用示例

示例1：

@echo off 
::设置CMD窗口字体颜色为0a 在CMD中输入命令 color /? 可查看颜色列表
color 0a
::设置CMD窗口显示模式为100列宽 20行高
MODE con: COLS=100 LINES=20
echo  -------------------
echo    choice 命令示例
echo  -------------------
echo.
echo.
:: /c按键列表 /m提示内容 /d默认选择 /t等待秒数   /d 必须和 /t同时出现
choice  /c abcde /m "请输入" /d e /t 5
 
::用户选择的结果会按项目序号数字（从1开始）返回在errorlevel变量中
if %errorlevel%==1 echo 你选择了a
if %errorlevel%==2 echo 你选择了b
if %errorlevel%==3 echo 你选择了c
if %errorlevel%==4 echo 你选择了d
if %errorlevel%==5 echo 你选择了e

示例2：

@echo off
echo ***安装并启动mysql请输入1
echo ***启动Tomcat请输入2
echo *******************************************
echo 备注：
echo 1.通过关闭tomcat运行窗口关闭Tomcat###
echo 2.以下为mysql启动及关闭操作###
echo *******************************************
echo ***启动mysql请输入3
echo ***关闭mysql请输入4

choice /C 1234 /m ""
if %errorlevel%==1 goto installmysql
if %errorlevel%==2 goto starttomcat
if %errorlevel%==3 goto startmysql
if %errorlevel%==4 goto stopmysql
:installmysql
echo "设置Mysql环境变量"
setx PATH "%PATH%;D:\iwhereEarth\mysql-5.6.39-winx64\bin" /m
echo "设置Mysql环境变量成功"
echo "安装MYSQL"
pushd D:\iwhereEarth\mysql-5.6.39-winx64\bin
mysqld install
net start mysql
echo "Mysql安装并启动成功"
goto end
:starttomcat
echo "启动Tomcat"
start cmd /k "d:&&cd D:\iwhereEarth\apache-tomcat-7.0.63\bin&&echo Tomcat运行窗口&&catalina.bat run"
goto end
:startmysql
pushd D:\iwhereEarth\mysql-5.6.39-winx64\bin
net start mysql
goto end
:stopmysql
pushd D:\iwhereEarth\mysql-5.6.39-winx64\bin
net stop mysql
goto end
:end
echo.&pause

3 批处理|脚本设置环境变量

::set system environment variable

::set ant environment variable
setx ANT_HOME E:\tools\apache-ant-1.9.0 /m
setx PATH "%PATH%;%ANT_HOME%\BIN" /m

::set android environment variable
SETX ANDROID_HOME E:\android\android-sdk-windows /m
SETX PATH "%PATH;%ANDROID_HOME%\platform-tools" /m

echo "设置成功"
pause
exit

4 批处理|局域网备份

4.1 环境

windows server 2000 (理论上可以用于所有windows)

4.2 问题说明

创建以下批处理bat文件，拷贝文件及移动文件到指定位置，Z盘为网络映射盘符。

添加计划任务，定时执行脚本。任务执行时，显示执行完成，但bat文件中脚本命令并没有执行。根据网上方法另存为ANSI编码文件；添加执行用户及密码，都不行。最后在一篇文章中找到方法。

echo ****#####start备份#####**** >>F:\shell\day1.log
xcopy d:\usr\sap\*.* z:\sap\D /E /H /R /Y /I /d >>F:\shell\day1.log
echo %date%."success backup d sap" >>F:\shell\day1.log
move /Y H:\backup\*.* z:\sap\database >>F:\shell\day1.log
echo %date%."success move databackup files" >>F:\shell\day1.log

4.3 问题解决

4.3.1 参考资料

http://blog.csdn.net/tzysf/article/details/51302039

https://social.microsoft.com/Forums/zh-CN/cc080642-9368-467a-b781-d108f1d6c214/windows-server-2003-scheduled-taskbat?forum=windowsxpzhchs

4.3.2 处理方法

在脚本开头添加如下命令

NET USE Z: \\XXX.XXX.XXX.XXX\D$\XXXX "Password" /User:"Administrator"

例子： NET USE Z: \\172.0.0.22\backup "Password" /User:"Administrator"

Z: #网络映射启动器盘符

172.0.0.22 #网络映射远程主机的ip地址

Password 和Administrator #连接远程网络驱动器的用户名、密码（远程主机的授权账户密码）

NET USE Z: \\172.0.0.22\backup "Password" /User:"Administrator"
echo ****#####start备份#####**** >>F:\shell\day1.log
xcopy d:\usr\sap\*.* z:\sap\D /E /H /R /Y /I /d >>F:\shell\day1.log
echo %date%."success backup d sap" >>F:\shell\day1.log
move /Y H:\backup\*.* z:\sap\database >>F:\shell\day1.log
echo %date%."success move databackup files" >>F:\shell\day1.log

就是在脚本开始，添加连接到驱动器的命令，脚本执行时不知道为什么没有默认确定连接账户密码。

5 在cmd/bat脚本中获取当前脚本文件所在目录

在xp、2000、2003等系统中都可以正常双击运行。在win7/Win10系统中双击运行时，会以普通用户身份运行，此时所获取的文件路径的确是当前路径，而不是C:\Windows\System32。但是运行到安装netpay_Service.exe -install 的系统服务时，普通用户显然权限是不够的。

于是在InstllSvc_En.cmd右键选择“以管理员身份运行”，此时又会出问题，win7/win10可能出于安全问题考虑，此时获得的目录是C:\Windows\System32，于是提示netpay_Service.exe命令无效或程序文件不存在，执行出错。

此时在脚本开始尝试加入命令cd %cd%，来获取当前路径，实验得知，这行语句在xp等系统中有效，但是在win7/win10中依然无效。得到的目录依然是C:\Windows\System32。

百度一下才知道要使用cd /d %~dp0命令来获取脚本所在的目录。在脚本最开始添加cd /d %~dp0即可，如下：

cd /d %~dp0
netpay_Service.exe -install
netpay_Monitor.exe -install

在Windows XP~Windows 10系统上运行此脚本，确认都没有问题。